Basic embedding tasks
Description
- ugvb.xls: Compiling a model into a BIM file, then load and run it. Passing parameters to a Mosel program (requires burglar5.mos, burglar.dat, prime4.mos, ugvb.bas)
- ugcb.xls: Redirecting Mosel output and error streams to a callback (requires burglar10.mos, burglar.dat, ugcb.bas)
Source Files
By clicking on a file name, a preview is opened at the bottom of this page.
Data Files
burglar5.mos
(!******************************************************
Mosel User Guide Example Problems
=================================
file burglar5.mos
`````````````````
Same as burglar2.mos but writes solution to a file.
(c) 2008 Fair Isaac Corporation
author: S. Heipcke, 2002, rev. 2006
*******************************************************!)
model Burglar5
uses "mmxprs"
parameters
OUTFILE="burglar_out.txt"
end-parameters
declarations
WTMAX = 102 ! Maximum weight allowed
ITEMS = {"camera", "necklace", "vase", "picture", "tv", "video",
"chest", "brick"} ! Index set for items
VALUE: array(ITEMS) of real ! Value of items
WEIGHT: array(ITEMS) of real ! Weight of items
take: array(ITEMS) of mpvar ! 1 if we take item i; 0 otherwise
end-declarations
initializations from 'burglar.dat'
VALUE WEIGHT
end-initializations
! Objective: maximize total value
MaxVal:= sum(i in ITEMS) VALUE(i)*take(i)
! Weight restriction
sum(i in ITEMS) WEIGHT(i)*take(i) <= WTMAX
! All variables are 0/1
forall(i in ITEMS) take(i) is_binary
maximize(MaxVal) ! Solve the MIP-problem
! Write out the solution to a file
fopen(OUTFILE,F_OUTPUT)
writeln("Solution:\n Objective: ", getobjval)
forall(i in ITEMS) writeln(" take(", i, "): ", getsol(take(i)))
fclose(F_OUTPUT)
end-model
| 
