FICO
FICO Xpress Optimization Examples Repository
FICO Optimization Community FICO Xpress Optimization Home
Back to examples browserPrevious exampleNext example

Basic LP tasks: problem statement and solving; solution analysis

Description
The first model (file chess.mos) is a small, introductory problem to modeling with Mosel that shows the basic features of the Mosel language:
  • formulation of a simple LP/IP problem
  • solving an optimization problem
  • solution printout
The second model (file chess2.mos) shows some more advanced features of Mosel, namely the data structures set and array:
  • formulating and solving a simple LP problem
  • defining a set of variables and an array of descriptions for the variables (to be used in the output printing)
Detailed solution information for MIP problems as may be required when performing sensitivity analysis, such as dual and reduced cost values (file chessfixg.mos) or ranging information for variables and constraints (file chessrng.mos), is not immediately available during or after the branch-and-bound search. The following procedure needs to be used to generate the sensitivity analysis data:
  1. Solve the MIP problem.
  2. Fix all discrete variables to their solution values.
  3. Re-solve the remaining LP problem.
  4. Retrieve the solution information.
Further explanation of this example: 'Mosel User Guide', Chapter 1 Getting started with Mosel and Section 8.1 Initializing sets, or the book 'Applications of optimization with Xpress-MP', Section 1.3 Solving the chess set problem.

chess.zip[download all files]

Source Files
By clicking on a file name, a preview is opened at the bottom of this page.
chess.mos[download]
chess2.mos[download]
chessfixg.mos[download]
chessfixgcb.mos[download]
chessrng.mos[download]




chessrng.mos

(!******************************************************
   Mosel Example Problems
   ======================

   file chessrng.mos
   `````````````````
   Display ranging information for variables and
   constraints in a MIP problem.

   * Solve the MIP problem
   * Fix all discrete variables to their solution values
   * Re-solve the remaining LP problem
   * Retrieve solution information for sensitivity analysis

   (c) 2008 Fair Isaac Corporation
       author: S. Heipcke, 2007, rev. Sep. 2022
*******************************************************!)

model "Chess (ranges)"
 uses "mmxprs"

 public declarations
  R = 1..2                               ! Index range
  DUR, WOOD, PROFIT: array(R) of real    ! Coefficients
  x: array(R) of mpvar                   ! Array of variables
  ifusesoft: mpvar                       ! Whether soft wood is used
  MTime, Wood: linctr                    ! Constraints
 end-declarations

 DUR   :: [3, 2]                         ! Initialize data arrays
 WOOD  :: [1, 3]
 PROFIT:: [5, 20]

 Wood:= sum(i in R) WOOD(i)*x(i) <= 200  ! Limit on raw material
                                         ! Add. capacity if using soft wood
 MTime:= sum(i in R) DUR(i)*x(i) <= 160 + 40*ifusesoft
 ifusesoft is_binary

 Profit:= sum(i in R) PROFIT(i)*x(i)

 setparam("realfmt","%.4g")              ! Set real number display format

 maximize(Profit)                        ! Solve the full MIP problem
 writeln("Solution: ", getobjval)

 fixmipentities                          ! Fix discrete variables
 maximize(XPRS_LIN, Profit)              ! Solve reduced problem as LP

 write("Objective sensitivity: ")
 writeln(getsensrng(XPRS_DN, Profit), " - ", getsensrng(XPRS_UP, Profit))

 writeln("Ctr: \tRHS DN, RHS UP")
 CtrSet:= {MTime, Wood}
 forall(c in CtrSet)
  writeln(" ", getname(c), ": \t", getsensrng(XPRS_DN,c),
                      ", ", getsensrng(XPRS_UP,c))
 writeln("Var: \tObj DN, Obj UP")
 forall(i in R)
  writeln(" x(", i, "): \t", getsensrng(XPRS_DN,x(i)),
                    ", ", getsensrng(XPRS_UP,x(i)))
end-model
Back to examples browserPrevious exampleNext example
© Copyright 2023 Fair Isaac Corporation.