FICO Xpress Optimization Examples Repository: Burglar - Exchange of information with embedded models

FICO Xpress Optimization Examples Repository

FICO Optimization Community

FICO Xpress Optimization Home

Burglar - Exchange of information with embedded models

Description

iodrvmem.c - working in memory ('mem' driver): compilation of a model held in memory to memory
iodrvmem2.c - working in memory ('mem' driver): compilation of a model file to memory (requires burglar2.mos, burglar.dat)
iodrvraw.c - binary data format ('raw' driver): compilation of a model held in memory to memory
iodrvraw2.c - binary data format ('raw' driver): working with physical model files (requires burglar2r.mos)
iodrvcb.c - output to callback functions ('cb' driver); working with system file descriptors ('sysfd' driver)
burgbindata.[c|java], - use of 'bin:' / BinDrv for reading and writing (requires burglar2m.mos)

For Java and .NET versions see the subdirectories C2 and D3 of the Mosel User Guide examples folder.

Further explanation of this example: Whitepaper 'Generalized file handling in Mosel', Sections 6 Exchange of information with embedded models, 7 bin: using Mosel's binary format

burgioc.zip

[download all files]

Source Files

By clicking on a file name, a preview is opened at the bottom of this page.

iodrvmem.c	[download]
iodrvmem2.c	[download]
iodrvraw.c	[download]
iodrvraw2.c	[download]
iodrvcb.c	[download]
burgbindata.c	[download]
burgbindata.java	[download]
burglar2.mos	[download]
burglar2r.mos	[download]
burglar2m.mos	[download]

Data Files

burglar.dat

[download]

burglar2r.mos

(!******************************************************
   Mosel Example Problems
   ====================== 

   file burglar2r.mos
   ``````````````````
   Use of I/O drivers for data handling.

   *** Not intended to be run standalone
       - run from iodrvraw2.c or runburglario*.mos ***
   
   (c) 2008 Fair Isaac Corporation
       author: S. Heipcke, 2004, rev. Sep. 2018
*******************************************************!)

model Burglar2r
 uses 'mmxprs'

 parameters
  IODRV='raw:'
  DATA='BurgData'
  SOL='SolTake'
  WTMAX = 102                    ! Maximum weight allowed
 end-parameters

 declarations
  public ITEMS: set of string    ! Index set for items
  VALUE: array(ITEMS) of real    ! Value of items
  WEIGHT: array(ITEMS) of real   ! Weight of items
  SOLTAKE: array(ITEMS) of real  ! Solution values
 end-declarations

 initialisations from IODRV
  [VALUE,WEIGHT] as DATA
 end-initialisations

 declarations
  take: array(ITEMS) of mpvar    ! 1 if we take item i; 0 otherwise
 end-declarations

! Objective: maximize total value
 MaxVal:= sum(i in ITEMS) VALUE(i)*take(i)

! Weight restriction
 sum(i in ITEMS) WEIGHT(i)*take(i) <= WTMAX

! All variables are 0/1
 forall(i in ITEMS) take(i) is_binary

 maximize(MaxVal)                ! Solve the problem

! Solution output
 forall(i in ITEMS) SOLTAKE(i):= getsol(take(i))

 writeln("Solution:\n Objective: ", getobjval)
 writeln(SOLTAKE) 

 initialisations to IODRV
  SOLTAKE as SOL
 end-initialisations

end-model