FICO
FICO Xpress Optimization Examples Repository
FICO Optimization Community FICO Xpress Optimization Home
Back to examples browserPrevious example

Overview of Mosel examples for 'Business Optimization' book

Description

List of FICO Xpress Mosel implementations of examples discussed in the book 'J. Kallrath: Business Optimization Using Mathematical Programming - An Introduction with Case Studies and Solutions in Various Algebraic Modeling Languages' (2nd edition, Springer, Cham, 2021, DOI 10.1007/978-3-030-73237-0).

List of provided model files

(Examples marked with * are newly introduced in the 2nd edition, all other models have been converted from the mp-model versions that were provided with the 1st edition of the book in 1997.)
FilenameDescriptionSection
absval.mos Modeling absolute value terms (linearization) 6.5
*absval2.mos, absval2a.mos Modeling absolute value as general constraints 6.5
bench101.mos Parkbench production planning problem (solution to Exercise 10.1) 10.9
bench102.mos Parkbench production planning problem, MIP problem (solution to Exercise 10.2) 10.9
blend, blend_graph Ore blending problem 2.7.1
*boat.mos Boat renting problem (solution for Exercise 3.3) 1.4.1, 3.7
*boat2.mos Multi-period Boat renting problem 1.6
boatdual.mos Dual of the Boat renting problem (solution for Exercise 3.3) 3.7
brewery.mos Brewery production planning (data files: brewery.xlsx, brewdata.dat) 8.3
burgap.mos Generalized assignment problem (solution for Exercise 7.3) 7.10
burglar Small knapsack problem 7.1.1
buscrew.mos Bus crew scheduling 7.8.4
calves.mos Calves and pigs problem 3.3.1
carton.mos Carton production scheduling problem (data file: carton.dat) 10.3
*ch-2tri.mos Minimal perimeter convex hull for two triangles 10.3
*contract.mos, contract_graph Contract allocation problem with semi-continuous variables 10.2.1
couples.mos Feasibility puzzle problem (solution for Exercise 6.5) 6.11
dea.mos Data envelopment analysis (solution for Exercise 5.2) 5.3
dual.mos Dual problem for a small LP (solution for Exercise 3.1b) 3.5.1
*dynbigm.mos Dynamic computation of big-M coefficients for production planning 14.1.2.1
*dynbigm2.mos Production planning problem formulation using indicator constraints 14.1.2.1
*ea_smpld.mos Evolutionary algorithm for supply management 14.1.3.3
euro.mos Choosing investment projects (solution for Exercise 7.5) 7.10
flowshop.mos, flowshop_graph Flowshop scheduling problem (solution for Exercise 7.7) 7.10
*fracprog.mos Fractional programming example 11.1
gap.mos Generalized assignment problem (solution for Exercise 7.2) 7.10
*goalprog.mos Lexicographic Goal Programming 5.4.3
*lagrel.mos Lagrange relaxation applied to the GAP 14.1.3.3
lim1.mos, coco Multi-period, multi-site production planning, LP model (solution for Exercise 5.1) 5.3
lim2.mos, coco_fixbv Multi-period, multi-site production planning, MIP model (solution for Exercise 6.7) 6.11
*manufact.mos Production scheduling problem with SOS formulation (solution for Exercise 6.9) 6.11
multk.mos Multi-knapsack problem (solution for Exercise 7.4) 7.10
network.mos Network flow problem (solution for Exercise 4.3) 4.7
network2.mos Generic formulation of network flow problem (Exercise 4.3) 4.7
*newsvendor.mos Newsvendor problem: 2-stage stochastic programming 11.3.2.1
npv.mos Net present value problem (solution for Exercise 6.8) 6.11
*optgrid.mos, optgrid2.mos Optimal breakpoints for piecewise linear approximation 14.2.3
*portfolio.mos Multi-stage stochastic portfolio investment model 11.3.2.5
primal.mos Primal problem for a small LP (solution for Exercise 3.1a) 3.7
prodx.mos Simple production planning example 2.5.2
projschd.mos, projplan_graph Project scheduling case study 10.2.3
quadrat.mos Linearized quadratic programming example 11.4
*quadrat2.mos Quadratic programming example solved as NLP 11.4
set.mos Set covering problem (solution for Exercise 7.6) 7.10
simple1.mos Simple LP problem (solution for Exercise 2.2) 2.13
simple2.mos Simple LP problem (solution for Exercise 2.3) 2.13
slab.mos Lifting slabs (solution for Exercise 6.6) 6.11
sludge.mos Sludge production planning example illustrating recursion 11.2.1
*sludge2.mos Recursion example solved as NLP 11.2.1
*teams.mos (solution for Exercise 6.4) 6.11
trim1.mos Trimloss problem LP formulation (solution for Exercise 4.1) 4.1.1
trim2.mos Trimloss problem MIP formulation (solution for Exercise 4.2) 4.1.2
*trimminlp.mos Trimloss problem formulated as a MINLP problem 13.3
*trimminlp2.mos Alternative NLP solver choice for trimloss problem 13.3
tsp.mos Traveling salesman problem (solution for Exercise 7.1) 7.10
*vrp, vrp_graph Vehicle routing - heating oil delivery problem 7.2.3
*woods.mos (solution for Exercise 2.1) 2.13
yldmgmt.mos Yield management, financial modeling 8.4.2

bsnsoptbook_ovw.zip[download all files]

Source Files

Data Files





brewery.mos

(!*********************************************************************
   Mosel Example Problems
   ======================

   file brewery.mos
   ````````````````
   Brewery distribution problem 
   
     Example discussed in section 8.3 of
     J. Kallrath: Business Optimization Using Mathematical Programming -
     An Introduction with Case Studies and Solutions in Various Algebraic 
     Modeling Languages. 2nd edition, Springer Nature, Cham, 2021 

   author: S. Heipcke, June 2018

   (c) Copyright 2020 Fair Isaac Corporation
  
    Licensed under the Apache License, Version 2.0 (the "License");
    you may not use this file except in compliance with the License.
    You may obtain a copy of the License at
 
       http://www.apache.org/licenses/LICENSE-2.0
 
    Unless required by applicable law or agreed to in writing, software
    distributed under the License is distributed on an "AS IS" BASIS,
    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
    See the License for the specific language governing permissions and
    limitations under the License.

*********************************************************************!)

model 'brewery'
  uses "mmxprs"

  declarations
    NALES:integer                 ! Number of ales
    NLAGER:integer                ! Number of lagers
    NP:integer                    ! Number of packaging units
    ND:integer                    ! Number of demand points
    NC:integer                    ! Number of commodity types
    NT:integer                    ! Number of container types
    NB:integer                    ! Number of breweries
  end-declarations

(!
  initializations from 'brewdata.dat'
    NALES NLAGER NP ND NC NT NB
  end-initializations
!)
  initializations from 'mmsheet.xlsx:brewery.xlsx'
    NALES NLAGER NP ND NC NT NB
  end-initializations

  declarations
    NL= NALES + NLAGER            ! Calculate number of liquid types
    RP=1..NP                      ! Packaging units
    RB=1..NB                      ! Breweries
    RT=1..NT                      ! Container types
    RD=1..ND                      ! Demand points
    IL=1..NL                      ! Liquids
    IC=1..NC                      ! Commodity types

    CTBP: array(RP,RB) of real    ! Unit transport cost from brewery b
                                  ! to packaging unit p
    CTPD: array(RT,RD,RP) of real ! Unit transport cost of packtype t
                                  ! from packaging unit p to demand point d
    RL: array(IC) of real         ! Liquid required by commodity c
    RC: array(IC) of integer      ! Container type required by commodity c
    CB: array(RB,1..2) of real    ! Brewing capacity at brewery b
                                  ! 1->Ale    2->Lager
!  CP: array(RP) of real        ! Total packaging capacity
    CP: array(RP,RT) of real      ! Total packaging capacity
    DEMAND: dynamic array(IC,RD) of real ! Final demand for commodity c
                                  !  at demand point d
    IBL: array(IL,RB) of real     ! 1 if brewery b can brew liquid l
    IBL1: array(IL) of real       ! Number of breweries that can brew liquid l
    BU: array(IL) of real         ! Maximum amount that can be brewed of l
    BL: array(RB) of real         ! Minimum brew quantity at b
    PU,PL: array(RP) of real      ! Max/min amounts that can be packed at p
  end-declarations

(!
  initializations from 'brewdata.dat'
    CTBP RL RC CB CP IBL DEMAND CTPD BL PL BU
  end-initializations
!)

  initializations from 'mmsheet.xlsx:brewery.xlsx'
    CTBP CTPD
    [RL,RC] as "Commodities"
    CB as "partndx;BreweryCap(#1,#2,#3)"
    CP as "partndx;PkgContainer"
    IBL as "partndx;BreweryLiq"
    DEMAND  
    BL  as "BreweryCap(#1,#4)"
    [PL,PU] as "PkgCap" 
    BU
  end-initializations
 
  forall(p in RP) PL(p):= 0
  forall(p in RP,t in RT) CP(p,t):= PU(p)
  forall(b in RB) BL(b):=0
  forall(l in IL) BU(l):=BU(l)*10
  forall(b in RB,l in IL)IBL(l,b):=1 

!  forall(p in RP) PU(p):= CP(p)
  forall(l in IL) IBL1(l):= sum(b in RB) IBL(l,b)

  
  declarations
    brew: dynamic array(IL,RB) of mpvar   ! Amount of l brewed at b
    beta: dynamic array(IL,RB) of mpvar   ! If any l brewed at b
    s: dynamic array(IL,RP) of mpvar      ! Throughput of l at p
    delta: dynamic array(IL,RP) of mpvar  ! If any l through p
    ! Amount of liquid type l sent from brewery b to packaging unit p
    ! (only defined if brewery b can brew liquid l)
    lq: dynamic array(RB,IL,RP) of mpvar     
    ! Amount of commodity c packed at packaging unit p
    ! (only defined if packaging unit p can pack packtype of c)
    pack: dynamic array(IC,RP) of mpvar
    ! Quantity of commodity c sent from packaging unit p to demand point d
    ! (only defined if packaging unit p can pack packtype of c and there
    ! is a demand for c at d)
    x: dynamic array(RP,IC,RD) of mpvar
  end-declarations

  forall(l in IL,b in RB| IBL(l,b)=1) create(brew(l,b)) 
  forall(l in IL,b in RB| IBL(l,b)=1 AND IBL1(l)> 1) create(beta(l,b))
  forall(l in IL,p in RP| PU(p)<>0)   !CP(p)<>0.0)
    create(s(l,p))
  forall(l in IL,p in RP|  PU(p)<>0)   !CP(p)<>0.0)
    create(delta(l,p))
  forall(b in RB,l in IL,p in RP| IBL(l,b)=1) create(lq(b,l,p))
  forall(c in IC,p in RP|  CP(p,RC(c))<>0)   !CP(p)<> 0)
    create(pack(c,p))
  forall(p in RP,c in IC,d in RD| CP(p,RC(c))<> 0 AND DEMAND(c,d)<>0)   !CP(p)<> 0)
    create(x(p,c,d))

  ! Objective function - minimise transport costs
  TransCost:= sum(b in RB,l in IL,p in RP) CTBP(p,b)*lq(b,l,p) +
            sum(p in RP,c in IC,d in RD) CTPD(RC(c),d,p)*x(p,c,d)

  ! Liquid balance at breweries
  forall(b in RB,l in IL)
    BBAL(b,l):= sum(p in RP) lq(b,l,p) = brew(l,b)

  ! Throughput of packaging units
  forall(l in IL,p in RP)
    PBAL(l,p):= sum(c in IC|RL(c)=l) pack(c,p) = s(l,p)

  ! Capacity limits of breweries
  forall(b in RB)
    BrCAPA(b):= sum(p in RP,l in 1..NALES) lq(b,l,p)<= CB(b,1)
  forall(b in RB)
    BrCAPL(b):= sum(p in RP,l in NALES+1..NL) lq(b,l,p)<= CB(b,2)

  ! Flow conservation in packaging units
  forall(p in RP,l in IL)
    PUL(p,l):= sum(c in IC| RL(c)=l) pack(c,p) =
                          sum(b in RB) lq(b,l,p)

  ! Capacity limits of packaging units
  forall(p in RP)
    PUC(p):= sum(c in IC) pack(c,p)<= PU(p)  !CP(p)

  ! Flow conservation per commodity
  forall(p in RP,c in IC)
    AVL(p,c):= sum(d in RD) x(p,c,d) = pack(c,p)

  ! Satisfy demands per commodity
  forall(c in IC,d in RD | exists(DEMAND(c,d)))
    Dm(c,d):= sum(p in RP) x(p,c,d) = DEMAND(c,d)

  ! Minimum and maximum packaging capacities
  forall(l in IL,p in RP)
    UBP(l,p):= s(l,p)<= PU(p)*delta(l,p)
  forall(l in IL,p in RP)
    LBP(l,p):= s(l,p)>= PL(p)*delta(l,p)

  ! Total brewery capacities
  forall(l in IL,b in RB|IBL1(l)>1) 
    UBB(l,b):= brew(l,b)<= BU(l)*beta(l,b)
  forall(l in IL,b in RB|IBL1(l)>1) 
    LBB(l,b):= brew(l,b)>= BL(b)*beta(l,b)

  forall(l in IL,p in RP | exists(delta(l,p)))
    delta(l,p) is_binary
  forall(l in IL,b in RB | exists(beta(l,b)))  
    beta(l,b) is_binary

 ! Solve the problem
  minimise(TransCost)
  writeln("Solution: Cost=", getobjval)

  forall(b in RB) do
    write("Brewery ",b, ":")
    forall(l in IL,p in RP | lq(b,l,p).sol>0)
      write("  Liq", l, "->Pkg", p, ":", lq(b,l,p).sol)
    writeln
  end-do
  forall(p in RP) do
    write("Pkg unit ",p, ":")
    forall(c in IC | or(d in RD | x(p,c,d).sol>0) true) do
      write("  Cont", c)
      forall(d in RD | x(p,c,d).sol>0) write(" ->Dem", d, ":", x(p,c,d).sol)
      writeln
    end-do
  end-do

end-model

Back to examples browserPrevious example